6. AutoHotKey - Recent Threads

I need a AHK script to implement copying multiple lines of text to the corresponding multiple lines in the translation box

Jack Zhai — Tue, 14 Oct 2025 01:09:21 GMT

I need a AHK script to implement copying multiple lines of text to the corresponding multiple lines in the translation box

AutoHotKey to toggle Autopropagation on and off

Stephen Rimmer — Sun, 24 Aug 2025 15:04:37 GMT

Trados Studio 2024. I regularly receive some large files where the CM is corrupted and the client does not want to clean up the TM. I need to toggle Autopropagation on and off quickly. Studio does not have a shortcut set up to do this, and going into Options every time is time consuming. Does anyone have an AutoHotKey script available? Many thanks.

"Clear AT statuses" AutoHotKey script doesn't work anymore in Trados studio 2024 SR1

Alessia Vonau — Fri, 22 Aug 2025 12:43:21 GMT

Hello,

since I've donwload the Trados Studio 2024 SR1 (some days ago - august 2025) the "Clear AT statuses" AutoHotKey sript doesn't work anymore.

The others AutoHotKey scripts work perfectly.

Here my "Clear AT statuses" AutoHotKey sript:

^+f::
Send ^a^c!{Ins}^a^v
Return

Does somebody experience the same and/or can help me please?

Paul Filkin?

Marking "Find and Replace" checkboxes as checked.

Andrus Lauringson — Wed, 06 Aug 2025 21:23:36 GMT

I am trying to write an Autohotkey 2.0 script that opens the "Find and Replace" window and marks two checkboxes as checked:

    WinActivate "Trados Studio - "
    WinWaitActive "Trados Studio - ", , 4
    Send("^f")
    WinWaitActive "Find and Replace", , 4
    ControlSetChecked 1, "&Match case", "Find and Replace"
    ControlSetChecked 1, "M&atch whole word", "Find and Replace"
    ControlSetChecked 1, "&Target", "Find and Replace"

The first time when I run it, it works great. But second time the checkboxes get unchecked. Does anyone have an idea what could be the problem?

Find&Replace window on top again

Valeria Maria Tafel — Thu, 06 Mar 2025 10:58:13 GMT

Hello, possibly to @PaulFilkin, who helped me on this issue a few months ago,
I'm in trouble again with the F&R window that remains stuck on top of any page in my PC. Could be after the last Trados update?

I tried to repeat the AutoHotkey actions that were recommended to me, but to no avail. In addition to that, my antivirus is telling me that the script has a virus.

Can someone help?

Thanks in advance

How to get rid of shortcut doublets in Studio 2024?

Cora Fröhlich — Thu, 14 Nov 2024 15:56:19 GMT

Does anybody know how to get rid of double shortcut names in the shortcuts window? Unfortunately, I cannot use one of my favorite shortcuts "edit comment" because somehow it is there twice now. As you can see, concordance search is doubled, too. Since I need to edit comments quite often, it is very annoying to have to edit them with a right-click.

I already uninstalled all older versions of Studio.

AI intro to AutoHotkey

Jesús Prieto — Thu, 07 Nov 2024 09:54:31 GMT

As an intro to AutoHotkey, you can listen to this podcast: https://media.publit.io/file/GeneralContent/AutoHotkey-podcast.html?player=TACMain

Before you do it, please read my comments below: 😀

I agree with what it’s said in the podcast, that’s why I posted it here. Now, it looks like a dialog between two people, but believe it or not it’s actually AI-generated content!

Anyway, It’s impressive the way comparisons are used, how questions are made and the answers given, the tone used, and the final change in volumen, mimicking the effect caused by a podcaster talking to a mic. If I weren’t told it was an AI and a couple of sound glitches, I would have thought it was real.

I said impressive, but also in shock in a negative way. I promised myself I would never read AI-generated blog-posts, now I don’t know if I’m ready to distinguish AI-generated podcasts.

If interested, it seems that the tool NotebookLM was used to create the above podast (I had never heard of it before). I guess this tool was fed with some AutoHotkey human-generated content and then the tool generates autommatical the questions and answers you see. I know nothing else, sorry.

AutoHotKey script for choosing translaton suggestion from AI Assistant

Emi Amber — Sat, 05 Oct 2024 16:42:43 GMT

Hei,

I have tried to write an AutoHotKey script for automatically replacing suggestions from OpenAi provider with suggestion from AI Assistant (keyboard shortcut Alt+W), confirm and go to the next segment. I wanted to automatize this process by pressing F9 key. It seems though that my script has some error, because what happens after applying F9 is that the translation from Open Ai is chosen anyway, not the suggestion from AI Assistant.

Do you have any suggestions what should be replaced in my script?

Thank you so much for your help in advance.

; AutoHotkey script to apply translation suggestion from AI Assistant,
; confirm the current segment, and move to the next segment in SDL Trados Studio

; Set a hotkey (e.g., F9) to trigger the commands
F9::
; Activate SDL Trados Studio window
WinActivate, ahk_exe TradosStudio2024_18.0.0.1013.exe ; Adjust the executable name if necessary

; Send the command to apply translation suggestion
; Replace with the actual shortcut you use to apply AI suggestion if needed
Send, ^a ; Assuming Alt+W applies the suggestion

; Confirm the current segment
Send, ^{Enter} ; Assuming Ctrl+Enter confirms the segment

return

What are some practical examples of how AutoHotkey can streamline the translation process for translators? and Can you share tips on writing effective scripts in AutoHotkey that specifically cater to the needs of translators?

ethar tarayrah — Wed, 02 Oct 2024 09:19:18 GMT

What are some practical examples of how AutoHotkey can streamline the translation process for translators?
and Can you share tips on writing effective scripts in AutoHotkey that specifically cater to the needs of translators?

Trados Clinics Webinar on AutoHotKey

Paul Filkin — Wed, 18 Sep 2024 09:36:12 GMT

Hi,

I wanted to share this link to a webinar that Jesús Prieto and myself delivered this morning in the Community Solutions Hub (Trados):

uat.community.rws.com/.../5580

It's designed to help users get started with AutoHotKey and might be worth a watch if you have not used it before. For more experienced users there is some interesting (I found it interesting anyway!) parts where we looked at tools that can be used, and some references to places to find additional help.

Hope it's useful!

Issue with AutoHotkey Scripts in SDL Trados Studio 2022 + Babylon does not work as Studio 2022 seems to block third part copying (Studio 2021 works without a problem)

Sameh Elsharkawy — Sat, 13 Jul 2024 18:42:38 GMT

Dear Support Team,

I am experiencing an issue with AutoHotkey scripts in SDL Trados Studio 2022. The same scripts work perfectly in SDL Trados Studio 2021 but fail to function as expected in the 2022 version. I would appreciate your assistance in diagnosing and resolving this problem. The same thing goes for Babylon Glossary engine, which works with the middle mouse from any application on Windows, and it works with all Windows applications except for Studio 2022, as it does not seem to be able to copy the highlighted word or words. Nevertheless, Babylon and AHK scripts work fine with SDL Studio 2021, so I wonder what could be going wrong! This is really a serious and disrupting issue for me, so please help. See a detailed video below and please pardon the voice as that is an issue that sometimes happens because of my sound card effect.
Please find attached an AHK script to double check in both Studio 2021 and 2022. I hope you can really solve this issue soon. I sent you a clear demo and if Studio 2021 works then definitely Studio 2022 should.

Sincerely,

Sameh Ragabuat.community.rws.com/.../2514.babylon-and-ahk-scripts.mp4

Define -Translate -Synonyms of Highlighted using Copilot

Muhammad Khateeb — Mon, 08 Apr 2024 18:54:15 GMT

Hello all

I want to use AHK to do :
1- explain/define the highlighted terms

2- Translate to Arabic

3- Give Synonyms - Examples of use.

what is wrong in this code

; Example AHK script to achieve the desired functionality
; When Ctrl+F6 is pressed while text is highlighted, a menu pops up with prompts to choose from

^F6::
    ; Get the highlighted text
    Clipboard := ""
    Send ^c
    ClipWait, 1

    ; If text is not empty, show the menu
    if (Clipboard != "")
    {
        Menu, MyMenu, Add, Define/Explain the highlighted term, DefineExplain
        Menu, MyMenu, Add, Translate the highlighted into (Language - Arabic), TranslateArabic
        Menu, MyMenu, Add, Suggest synonyms of the highlighted, Synonyms
        Menu, MyMenu, Show
    }
return

DefineExplain:
    ; Send the prompt to Copilot
	Run, https://copilot.microsoft.com/
    SendInput define/explain the highlighted term
return

TranslateArabic:
    ; Send the prompt to Copilot
	Run, https://copilot.microsoft.com/
    SendInput Translate the highlighted into (Language - Arabic)
return

Synonyms:
    ; Send the prompt to Copilot
	Run, https://copilot.microsoft.com/
    SendInput suggest synonyms of the highlighted with examples of use
return

Is there any way of addressing the project list in Trados Studio?

Stefan Keller — Sat, 27 Jan 2024 11:25:24 GMT

Hi all,

I was wondering if it's possible to read values from the project list with AutoHotkey. In particular, when working with WorldServer packages, I am so sick of Studio always defaulting to the last used target directory when I export a package. So I'm desperately trying to create a script that can read the location of the selected project in the list. Any help or hints would be much appreciated.

Thanks,
Stefan

Adding multiple chunks of text to the clipboard

James Plastow — Fri, 20 Oct 2023 20:48:00 GMT

This is about as simple as AHK can be, but I thought I would share it as I find it quite useful. This script lets you accumulate multiple chunks of text on the clipboard and then paste them all at the end. It can be used, for example, when a client wants you to translate specific sections of text in a document and you want to quickly collect just those parts and then paste them into a blank document. Much simpler and easier than copying and pasting multiple items one at a time.

(Just use control + shift + c / v to use this script)

global multiclip
^+c::
send, ^c
ClipWait
multiclip := multiclip . "`n" . clipboard
return

^+v::
clipboard := multiclip
send, ^v
return

Using AHK, how can I place the cursor in the editor?

Daniel Hug — Mon, 14 Aug 2023 12:09:11 GMT

I am writing a script that copies content from the Concordance view into the editor. I can select the concordance view using <ALT>, V, C, 2. But there seems to be no command to place the cursor back into the editor. ALT V D 2 selects the editor in the navigation, but not the editor view/window.

Get and insert synonyms from Microsoft Word

Jesús Prieto — Thu, 18 May 2023 15:43:15 GMT

Hi everyone!

It has been already discussed here: synonyms - like in MS Word
Now based on the post of Jack Dunning mentioned on the link above, the following AutoHotkey script grabs synonyms from Microsoft Word application. Then it’ll show a pop-up menu with the available meaning-synonyms and then insert the selected synonym (right submenu) in Trados (see figure below). Only synonyms (right submenu) are clickable.

Synonyms will be picked based on the top language set on File > Options > Language > Office authoring languages and proofing (Spanish [Spain] in my particular case. The proofing package must be installed in order to use it):

This is the AutoHotkey script:

;-------------------------------------------------
; Search for synonyms in Trados Studio using Microsoft Word app.
; Ensure Microsoft Word is running (otherwise, the script will run it for you).
; Select the word in Trados Studio Editor.
; Use the shortcut is SHIFT+F7 (the same as in Word)
; In the pop-up menu first select the meaning and then the synonym.
; The synonym selected will be inserted on the Target segment.
; learn.microsoft.com/.../word.application.synonyminfo
; learn.microsoft.com/.../word.synonyminfo.synonymlist
;------------------------------------------------
#IfWinActive ahk_exe SDLTradosStudio.exe
+F7::
   Send ^c
   if StrLen(A_Clipboard)
       SynonymsWord()
return
#IfWinActive


SynonymsWord(sel := "")
{
Global leadingSpace
Global trailingSpace
   Try
       oWord := ComObjActive("Word.Application")
   catch
   {
       Run, WinWord, , Min
       Loop
       {
           Sleep 200
           try
               oWord := ComObjActive("Word.Application")
           if (A_index > 60)
           {
               ME("Microsoft Word is not installed and no synonyms can be retrieved from Word.")
               return
           }
       } Until oWord!=""
   }

   if (sel = "")
       sel := A_Clipboard
   if (RegexMatch(sel, "^\s"))
       leadingSpace := SubStr(sel, 1, 1)
   else
       leadingSpace := ""
   if (RegexMatch(sel, "\s$"))
       trailingSpace := SubStr(sel, 0)
   else
       trailingSpace := ""
   sel := RegExReplace(sel, "^\s+") ; Remove leading spaces
   sel := RegExReplace(sel, "\s+$") ; Remove trailing spaces

   nMeanings := oWord.SynonymInfo(sel).MeaningCount
   meanings := oWord.SynonymInfo(sel).MeaningList
   StringUpper, selUpper, sel

   Menu, MenuSynonyms, add, %selUpper%, Nothing, +Radio
   Menu, MenuSynonyms, check, %selUpper%
   Menu, MenuSynonyms, default, %selUpper%
   Loop % nMeanings
   {
       try
           meaning := meanings[A_Index]
       catch
           continue

       nMeaning := A_Index
       mySubmenu := "MenuMeanings" nMeaning

       synonyms := oWord.SynonymInfo(sel).SynonymList(A_Index)
       max := synonyms.MaxIndex()
       Loop % max
       {
           synonym := synonyms[A_Index]
           Menu, %mySubmenu%, add, %synonym%, SynonymAction
       }
       Menu, MenuSynonyms, add, %meaning%, :%mySubmenu%
   }

   if (!nMeanings)
       Menu, MenuSynonyms, add, No synonyms from Word!, Nothing
   Menu, MenuSynonyms, Show

   Menu, MenuSynonyms, DeleteAll
   Loop
   {
       mySubmenu := "Meanings" A_Index
       try
           Menu, %mySubmenu%, Delete
       catch
           Break
   }
}

SynonymAction()
{
Global leadingSpace
Global trailingSpace
   SendRaw % leadingSpace A_ThisMenuItem trailingSpace
}

Nothing()
{

}

The script works not only in Trados Studio Editor, but also in Translation Memories, etc…
The out-of-the-box script works only in Trados Studio, but it can work also in other applications. Don’t hesitate to edit the script to suit your needs.
In case you are wondering if it’s possible to select the proofing language automatically based on the target language of the Studio project, yes, I think it is, but I leave to RWS to publish an app with this feature.

Enjoy!

Bring back the active off screen window with AutoHotkey

Jesús Prieto — Wed, 19 Apr 2023 11:35:56 GMT

Howdy!

The following script can bring back the Find and Replace window which sometimes goes off screen:
CoordMode, Mouse, Screen
^+m::
MouseGetPos, x, y
WinMove A,, %x%, %y%
return

Source: https://www.youtube.com/watch?v=YStr_W9acpw . Check minute 0:30.
Credits to Joe and Isaías.

A script to draw brackets on the screen to help with segmenting long sentences

James Plastow — Tue, 18 Apr 2023 18:20:13 GMT

A key part of the translation process is going through long sentences and figuring out the sections that make up the sentence that will need to be in the translation, but often in a different order.

This script allows you to add ( and ) marks on top of the screen to see these different parts of the sentence more clearly.

Just click Ctrl Shift Left button for ( and Ctrl Shift Right button for )

Note that these brackets are just placed on top of the screen so they will not move when you scroll or be saved in the file at all.

You can clear them by hitting Escape and they will also be cleared when you hit Ctrl Enter to confirm the segment

CoordMode, mouse, screen

^+Lbutton::
MouseGetPos, x, y
x2:=x-50
y2:=y-60
Gui, New
Gui, +LastFound +AlwaysOnTop +Owner -DPIScale -Caption
Gui, font, s26 cDA4F49
Gui, add, text,, (
WinSet, TransColor, f0f0f0
Gui, Show, X%x2% Y%y2%
return

^+Rbutton::
MouseGetPos, x, y
x2:=x-50
y2:=y-60
Gui, New
Gui, +LastFound +AlwaysOnTop +Owner -DPIScale -Caption
Gui, font, s26 cDA4F49
Gui, add, text,, )
WinSet, TransColor, f0f0f0
Gui, Show, X%x2% Y%y2%
return

~^Enter::
~Esc::
reload

Solving mid-sentence line breaks in PowerPoint

James Plastow — Tue, 28 Feb 2023 09:31:47 GMT

Often you receive a PowerPoint file from a client and you want to translate it in Trados, but it is full of line breaks in the middle of the sentences, which will create a mess of split segments when you open it in Trados. It is better to remove these line breaks before importing the PPT into Trados, but they are hard to find because, unlike in Word, there is no way to display linebreak characters in PowerPoint.

One way to solve this is to go through each text box in the PowerPoint and reduce the font size. This way the mid-sentence linebreaks become clear.

So, here is an AHK script to speed up that process as you will probably have a lot of text boxes to go through in a PPT presentation.

A very simple AHK script, but I think it is a useful one for translators nevertheless.

Press Control K to reduce the font size, delete any mid-sentence linebreaks manually, then press Control L to return to the original font size.

^k::
send ^a
sleep 100
send ^+{, 4}
Return

^l::
send ^a
sleep 100
send ^+{. 4}
Return

A script to convert numbers which have the full stop instead of a comma as a separator.

JMStuart — Tue, 21 Feb 2023 08:20:56 GMT

Here is a script to convert numbers which have the full stop instead of a comma as the "thousands" separator.
I found the 2 RegEx lines in the AutoHotKey forum.

A more advanced script would find the numbers in the source segment and replace the ones in the target segment, automatically.
And also do the full conversion including the decimal point as well.
So any suggestions for that are welcome!

Example: 123.456.789 --> 123,456,789

------------------------

; first you select the number in the source language segment and copy it (to the clipboard), then select the number in the target segment
; then press F2 to run the macro

F2::
clipboard := RegExReplace(clipboard, "(\d),(\d)", "$1$2")
clipboard := RegExReplace(clipboard, "(\d)\.(\d)", "$1,$2")
Sleep 150 ; give a little time for this operation to finish
send ^v
Return

Studio 2022 Find/Replace dialog box is always displayed on top

Joseph Macdonald — Thu, 12 Jan 2023 16:08:30 GMT

Hi folks
Does anyone know how to stop the Find/Replace dialog box from always being displayed on top?

In Studio 2017 when you clicked on another window/program the Find/Replace dialog box would then be in the background, below the clicked window/program and no longer in the way. In Studio 2022 it is always in the way (on top) so I either have to move it out of the way, or close it then open it again next time I need it.

This happens in Windows 10 and 11 so presumably it's something to do with Studio 2022. I recently updated Studio, no change.

Any ideas?

The Studio Find/Replace dialog box is always on top of any other window such as the browser as shown in this pic, also if I click in the browser window.

It's the only dialog box that does this. In Word for example the Search/Replace box goes to the background when clicking on Studio (or another program) and is displayed in the foreground when you click on Word again.

Here's what it looks like

Better smart quotation marks while typing (like in Word) for files and languages with missing settings

Pascal Zotto — Mon, 21 Nov 2022 16:29:40 GMT

Hi,

I’ve been fiddling around quite some time now in order to get it working without triggering errors in Trados Studio (beginning and end of line and first or last line, aso.) but now this gives custom quotation marks just like in Word. They are placed according to their relative position to the text (opening vs. closing) and not depending on if you already typed a quotation mark or not (existing script from Jesus Prieto (if I remember correctly)). It even works if you place the caret anywhere in your segment and type a ".

#IfWinActive, Trados Studio
"::
OldClipboard := % Clipboard
Clipboard := ""
Caretx := A_CaretX
Carety := A_Carety
MouseGetPos, Mousex, Mousey
Send ^a
Send ^c
ClipWait 1
if (ErrorLevel)
{
	send „ ;open
}
else
{
	MouseMove, % Caretx, % Carety
	Click, Left
	MouseMove, % Mousex, % Mousey
	Send, {shift down}{left}
	Send, {shift up}
	Send, ^c
	Send, {right}
	ClipWait, 2
	mycheck := Clipboard
	if (RegexMatch(mycheck,"[^\s]"))
	{
		send “ ;close
	}
	else
	{
		send „ ;open
	}
Clipboard := % OldClipboard
}
return
#IfWinActive

Notes:

I set it with code to only work in Trados Studio, if you want to use it anywhere just remove the first and the last line of the above code.

It is triggered if " (straight quotation marks (Shift +2 on German keyboard)) is typed, if you want another character as trigger, just replace the " in line ":: with the character you want.

This one uses German curly quotation marks but you can just replace the quotation marks with the ones you would like to by replacing the characters before the seceral ;open or ;close parts respectively. It could also be used for Spanish exclamation and question marks as they follow the same behaviour.

You might see your mouse cursor jump around, that’s intended, so no need to worry about it.

Best regards,

Pascal

Unexplained "Failed to create settings page" error

Zachary Mühlenweg — Mon, 14 Nov 2022 14:32:38 GMT

Hello,

I opened Trados today hoping to work as per usual and all of a sudden I cannot access the project settings for any of my projects. I receive the error "Failed to create settings page" every time I try (see error output below):

Failed to create setting page.

System.ArgumentOutOfRangeException, mscorlib, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089

Value

System.Windows.Forms

-2146233086

at System.Windows.Forms.DateTimePicker.set_Value(DateTime value) at Sdl.TranslationStudio.ProjectManagement.Settings.ProjectDetailsSettingsPageControl.set_SelectedDueDate(DateTime value) at Sdl.TranslationStudio.ProjectManagement.Settings.ProjectDetailsSettingsPageControl.set_Project(IProject value) at Sdl.TranslationStudio.ProjectManagement.Settings.ProjectDetailsSettingsPage.GetControl() at Sdl.Desktop.Platform.WinForms.SettingsUIControl._tree_AfterActivate(Object sender, NodeEventArgs e)

SDL Trados Studio

15.0.0.0

15.2.8.3007

Microsoft Windows 10 Home N

NULL

1031

1252

True

3122512 MB

I already tried to rename the folder and restart the app, as suggested in other threads, but to no avail. I really need to keep working and this is extremely frustrating. Any suggestions?

Cheers,

Zachary

virtual extended monitor

James Plastow — Tue, 06 Sep 2022 13:43:06 GMT

Recently I have been working on my laptop rather than a big screen, its nice to have the mobility to be able to work in different spots.

But obviously the problem is the limited screen space. So, I wrote this simple script to make it easier to use the "virtual desktops" function in Windows.

First you will need to set up one or more additional desktops by pressing Windows + Tab

Then, this script allows you to "move" between desktops very smoothly. Just click on the left or right sides of the screen.

~LButton::
MouseGetPos, x,y
if (x >=0 and x <=10)
{
send, ^#{left}
}

if (x >=2550 and x <=2560) ; Adjust this depending on your horizontal monitor resolution
{
send, ^#{right}
}
return

(Incidently, there is a bug in this Windows function where Excel windows appear on all desktops. In this case just pres Win Tab then right click on the Excel window and select which desktop the window should appear on)

To convert Encoding (UTF-8 with BOM or without BOM convert)

Kelly Edward — Wed, 29 Jun 2022 20:23:08 GMT

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; You select a file then
; It converts from "UTF-8 with BOM" to "UTF-8 without BOM" and vice versa
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; << Warning >>
; It does not make any BackUps, it deals with the file you selected directly.
; You'd better keep original one safely.

Attached: AutoHotkey source code

uat.community.rws.com/.../Encoding-Converter.zip